!----------------------------------------------------------------------!
!  PROTO.TAB 1.01                                                      !
!  Oct 95 (PJW)                                                        !
!                                                                      !
!  TABLO input file for PROTO, a simple static general equilibrium     !
!  model.                                                              !
!----------------------------------------------------------------------!

EQUATION    (default=levels);
VARIABLE    (default=levels);
FORMULA     (default=initial);
COEFFICIENT (default=parameter);

!----------------------------------------------------------------------!
!  These are the parameters:                                           !
!----------------------------------------------------------------------!

COEFFICIENT a;  FORMULA  a = 0.285;  ! Utility function parameter      !
COEFFICIENT b;  FORMULA  b = 2.040;  ! Production function parameter   !

!----------------------------------------------------------------------!
!  Here are the variables.  No distinction needs to be made between    !
!  endogenous and exogenous variables since that is determined when    !
!  the model is actually simulated.                                    !
!----------------------------------------------------------------------!

VARIABLE   h   # Total endowment of hours #;
VARIABLE   t   # Initial tax rate         #;
VARIABLE   p   # Numeraire price          #;
VARIABLE   y   # Income                   #;
VARIABLE   w   # Wage rate                #;
VARIABLE   s   # Subsidy to households    #;
VARIABLE   c   # Quantity consumed        #;
VARIABLE   l   # Labor supplied           #;
VARIABLE   j   # Leisure consumed         #;
VARIABLE   q   # Quantity produced        #;

!----------------------------------------------------------------------!
!  Exogenous variables                                                 !
!----------------------------------------------------------------------!

FORMULA p = 1.000;
FORMULA h = 100.0;
FORMULA t = 0.200;

!----------------------------------------------------------------------!
!  Here are base case values of variables appearing in coefficient     !
!  expressions.  These could be computed separately and stored in a    !
!  file for a larger model.                                            !
!----------------------------------------------------------------------!

FORMULA w = 1.040;
FORMULA y = 109.1863517;
FORMULA s = 5.186351706;
FORMULA l = 24.93438320;

!----------------------------------------------------------------------!
!  Finally, here are the equations:                                    !
!----------------------------------------------------------------------!

EQUATION eq1  y = w*h + s ;
EQUATION eq2  p*(1+t)*c = a*y ;
EQUATION eq3  w*j = (1-a)*y ;
EQUATION eq4  w*l = a*y - s ;
EQUATION eq5  l = q/b ;
EQUATION eq6  p = w/(b-1) ;
EQUATION eq7  t*p*c = s ;